提醒:本页面将不再更新、维护或者支持,文章、评论所叙述内容存在时效性,涉及技术细节或者软件使用方面不保证能够完全有效可操作,请谨慎参考!

写过PHP的都知道,其有个 extract() 非常方便,可以便捷的将字典转换为变量,当然到ASP中则要受限很多,特别是VBScript脚本,本文叙述的就是一种转换的思路,可以实现类似的功能。

首先需要我之前公布的一个类 DynamicObject (最新版本的),大家可以移步 这里 找到相应的代码和说明。

了解了 DynamicObject 类和其工作原理后,下面我就直接提供ASP版本的extract代码吧:

'
' ASP/VBScript Dictionary extract
' Author: WangYe
' For more information please visit
'     http://wangye.org/
' This code is distributed under the BSD license
'
' collection 集合或者字典,可以通过For Each访问的
'            Request.Form 或者 Request.QueryString
' specified  指定必须存在的属性,假如该属性不存在,将自动创建一个
' prefix     每个属性的前缀修饰
' callback   对于集合或者字典的每个元素(key-value)的值进行函数调用
'            函数原型:
'            Function filter(key, value)
'                filter = value
'            End If
'            最终值将以该函数返回的值为准
' 
Function extract(collection, ByVal specified, prefix, callback)
    Dim VarName, VarValue, DynObj, searchKey
    specified = "," & Replace(specified, " ", "") & ","
    
    Set DynObj = New DynamicObject
    For Each key In collection
        searchKey = "," & key & ","
        If InStr(1, specified, searchKey, 1)>0 Then
            specified = Replace(specified, searchKey, "")
            If Left(specified, 1) <> "," Then
                specified = "," & specified
            End If
            If Right(specified, 1) <> "," Then
                specified = specified & ","
            End If
        End If
        
        VarName = prefix & key
        
        VarValue = collection(key)
        If callback<>"" Then
            VarValue = GetRef(callback)(key, VarValue)
        End If
        
        DynObj.add VarName, VarValue, PROPERTY_ACCESS_READONLY
	Next
    
    specified_array = Split(specified, ",")
    Dim i
    For i = LBound(specified_array) To UBound(specified_array)
        If specified_array(i)<>"" Then
            DynObj.add prefix & specified_array(i), "", _
		PROPERTY_ACCESS_READONLY
        End If
    Next
    Set extract = DynObj.GetObject()
End Function

再介绍下使用方法:

Dim query
Set query = extract(Request.QueryString, "name,id", "", "")

    Response.Write query.name
    Response.Write query.id

Set query = Nothing

访问包含上述代码的ASP页面,在QueryString(就是URL问号后面的)包含 name=wangye 你将看到页面输出"wangye",包含 id=12 的时候,将输出"12",当然你也可以同时指定两项。

你可能发现当你Response.Write输出name和id之外key的时候,程序报错了,因为指定的属性不存在,当你在查询字符串包含这个key的时候,程序又正常了,因为有了这个key就自动建立了属性,所以又可以直接Response.Write了,如何避免呢?

1. 通过 extract() 函数的 specified 参数,该参数是个以逗号隔开key的字符串,你可以看到刚才示例代码中运用了这个特性,如果查询字符串未包含相应的key,但是你又使用了这个key,只要 specified 列表中有,就会自动建立值为空的属性,所以就不会报错啦。

2. 通过返回对象的 hasattr_ 方法进行使用前判断,这个方法可以判断 extract() 函数返回的对象是否存在相应的属性,比如代码有:

Dim query
Set query = extract(Request.QueryString, "name,id", "", "")

If query.hasattr_("job") Then
    Response.Write "Job : " & query.job
End If

Set query = Nothing

这里job并不在我们的 specified 列表中,但是不带查询字串的直接访问程序没有报错,因为我们通过 hasattr_ 在使用前进行判断是否存在此属性。

3. 通过返回对象的 getattr_ 方法进行安全访问,这个方法会在使用前判断指定的属性是否存在,如果不存在则用默认值替代,详细参考 DynamicObject 说明,比如代码:

Dim query
Set query = extract(Request.QueryString, "name,id", "", "")

    Response.Write "Job : " & query.getattr_("job", "No Job")

Set query = Nothing

最后再介绍下filter的使用, extract() 函数的 filter 参数,指定的是另外一个函数名字符串,然后 extract() 将对每个值调用该函数进行处理,比如过去有这样的代码:

Dim name, job, id
name = Trim(Request.QueryString("name"))
job = Trim(Request.QueryString("job"))
id = CLng(Trim(Request.QueryString("id")))

可以看到,我们每一次都调用了Trim()函数,重复的写多次很麻烦,而且以后如果要改变相应功能还要一个一个替换,通过 filter 参数我们可以这样写:

'
' Function filter(key, value)
'   filter = Trim(value)
' End Function
'

Function filter(key, value)
    On Error Resume Next

    Select Case key
        Case "id" ' 判断ID是否是数字
            If Not IsNumeric(value) Then
                Exit Function
            End If

            If CLng(value)<1 Then
                Exit Function
            End If
    End Select

    ' 最后记得让函数返回值,该值在extract将被置为该返回值
    filter = Trim(value)

    If Err.Number<>0 Then
        filter = ""
    End If
End Function

Dim query
Set query = extract(Request.QueryString, "name,id,job", "", "filter")

    Response.Write query.name
    Response.Write query.job
    Response.Write query.id

Set query = Nothing

刚才我们是以 Request.QueryString 为例子的,当然你也可以使用 Request.Form 来实现表单处理的更多功能,希望这篇文章能够给你编写ASP带来方便:-)